{ config, pkgs, lib, ... }:
with lib;
let
  cfg = config.aviallon.hardware.amd;
  devCfg = config.aviallon.developer;
  generalCfg = config.aviallon.general;
in {
  config = mkIf (cfg.enable && cfg.kernelDriver == "amdgpu") {
    boot.initrd.kernelModules = [ "amdgpu" ];

    aviallon.boot.cmdline = {
      # for Southern Islands (SI ie. GCN 1) cards
      "radeon.si_support" = 0;
      "amdgpu.si_support" = 1;
      # for Sea Islands (CIK ie. GCN 2) cards
      "radeon.cik_support" = 0;
      "amdgpu.cik_support" = 1;

      "amdgpu.ppfeaturemask" = mkIf generalCfg.unsafeOptimizations "0xfff7ffff";
      #"amdgpu.mes" = mkIf generalCfg.unsafeOptimizations 1;
      "amdgpu.seamless" = mkIf generalCfg.unsafeOptimizations 1;
    };

    environment.systemPackages = with pkgs; []
      ++ [ rocmPackages.rocm-smi ]
      ++ optionals devCfg.enable [
        rocmPackages.rocminfo
      ]
    ;

    aviallon.programs.config.rocmSupport = mkDefault devCfg.enable;

    services.xserver.videoDrivers = 
      optional cfg.useProprietary "amdgpu-pro"
      ++ [ "modesetting" ];

    hardware.opengl = {
      enable = true;
      extraPackages = with pkgs; mkIf (!cfg.useProprietary) (
        [
          rocmPackages.clr.icd
        ]
        ++ optional (cfg.defaultVulkanImplementation == "amdvlk") amdvlk
      );
      extraPackages32 = with pkgs.driversi686Linux; mkIf (!cfg.useProprietary) ([]
        ++ optional (cfg.defaultVulkanImplementation == "amdvlk") amdvlk
      );
    };

    systemd.tmpfiles.rules = [
      "L+    /opt/rocm/hip   -    -    -     -    ${pkgs.rocmPackages.clr}"
    ];

    environment.variables = {
      AMD_VULKAN_ICD = strings.toUpper cfg.defaultVulkanImplementation;
      ROC_ENABLE_PRE_VEGA = "1"; # Enable OpenCL with Polaris GPUs
    };

    # Make rocblas and rocfft work
    nix.settings.extra-sandbox-paths = [
      "/dev/kfd?"
      "/sys/devices/virtual/kfd?"
      "/dev/dri/renderD128?"
    ];

    nixpkgs.overlays = [(final: prev: {
        # Overlay Blender to use the HIP build if we have a compatible AMD GPU
        blender = final.blender-hip;
        blender-prev = prev.blender;
      })];
  };
}